hbios/tms: Added vram size detection for V99x8 chips

Source/HBIOS/tms.asm

@@ -6,11 +6,14 @@
 ; UPDATED BY: DEAN NETHERTON -- 5/26/2021 - V9958 SUPPORT
 ; UPDATED BY: JOSE L. COLLADO -- 11/15/2023 - MEMORY MAP CHANGES
 ; UPDATED BY: DAN WERNER -- 2/11/2024 - DUODYNE SUPPORT
-; UPDATED BY: DAN WERNER -- 11/271/2025 - N8PC SUPPORT
+; UPDATED BY: DAN WERNER -- 11/27/2025 - N8PC SUPPORT
+; UPDATED BY: DEAN NETHERTON -- 1/7/2026 - ADDED RUNTIME DETECTION OF CHIP TYPE AND VRAM SIZE
 
 ;======================================================================
 ;
 ; TODO:
+;   - CAN WE AUTO DETECT TMS VS V99x8 AND THUS AUTO SELECT TMS80COLS AT RUNTIME?
+;   - CAN WE AUTO DETECT TYPE FOR FPGA EMULATED VERSIONS?
 ;   - IMPLEMENT SET CURSOR STYLE (VDASCS) FUNCTION?
 ;   - IMPLEMENT ALTERNATE DISPLAY MODES?
 ;   - IMPLEMENT DYNAMIC READ/WRITE OF CHARACTER BITMAP DATA?
@@ -318,6 +321,10 @@ TMS_INIT:
 	RET
 ;
 TMS_INIT1:
+	CALL 	TMS_CRTINIT		; SETUP THE TMS/V99x8 CHIP REGISTERS
+					; THIS IS BEST DONE BEFORE DETECTION OF TYPE
+					; AND VRAM SIZE
+
 	CALL PRTSTRD
 	.TEXT	" VDP=$"
 
@@ -328,8 +335,8 @@ TMS_INIT1:
 	JR	NZ, TMS_NOT9918
 
 	CALL PRTSTRD
-	.TEXT	"TMS9918$"
-	JR	TMS_INIT2
+	.TEXT	"TMS9918 VRAM=16KB INTERRUPT=60HZ$"
+	JR	TMS_INIT3
 
 TMS_NOT9918:
 	DEC	A
@@ -345,11 +352,37 @@ TMS_NOT9938:
 	.TEXT	"V9958$"
 
 TMS_INIT2:
+	CALL PRTSTRD
+	.TEXT	" VRAM=$"
+
+	CALL	TMS_VRMPRB
+
+	DEC	A
+	JR	NZ, NOT_64K
+
+	PRTS("64KB$")
+	JR	TMS_INIT3
+
+NOT_64K:
+	DEC	A
+	JR	NZ, NOT_128K
+
+	PRTS("128KB$")
+	JR	TMS_INIT3
+
+NOT_128K:
+	PRTS("192KB$")
 
 #IF (TMSTIMENABLE)
 	CALL PRTSTRD
-	.TEXT	" INTERRUPT ENABLED$"
+#IF (TICKFREQ == 50)
+	.TEXT	" INTERRUPT=50HZ$"
+#ELSE
+	.TEXT	" INTERRUPT=60HZ$"
+#ENDIF
+
 #ENDIF
+TMS_INIT3:
 	CALL	PC_SPACE
 	LD	A,TMS_COLS
 	CALL	PRTDEC8
@@ -358,7 +391,6 @@ TMS_INIT2:
 	LD	A,TMS_ROWS
 	CALL	PRTDEC8
 ;
-	CALL 	TMS_CRTINIT		; SETUP THE TMS CHIP REGISTERS
 	CALL	TMS_LOADFONT		; LOAD FONT DATA FROM ROM TO TMS STRORAGE
 	; *** DIAGNOSE FONT LOAD ERROR HERE!!! ***
 	CALL	TMS_CLEAR		; CLEAR SCREEN, HOME CURSOR
@@ -840,6 +872,117 @@ TMS_IS9918_WAIT:
 
 	AND	01000000B		; CHECK IF BIT 6 WAS 0 (S#0 5S) OR 1 (S#2 VR)
 	RET
+
+; PROBE VRAM SIZE OF V99x8 VDP
+;
+; ASSUMES INTERRUPTS ARE DISABLED (DI)
+;
+; A <- 1: 64K, 2: 128K, 3: 192K
+TMS_VRMPRB:
+	XOR	A			; SET RETURN VALUE FOR 64K
+	INC	A
+	EX	AF,AF'
+	LD      A,4
+	; USE 16 BIT I/O ADDRESS FOR EZ80 COMPATIBILITY 
+	; (AVOID NEED FOR EZ80_IO MACRO)
+	LD	BC, (IO_SEGMENT<<8)+TMS_CMDREG
+	OUT     (C),A
+	CALL	DLY64			; DELAY
+	LD      A,$8E
+	OUT     (C),A			; R#14 = 4 -> A16 = 1, A15..A14 = 0
+	CALL	DLY64			; DELAY
+	XOR     A
+	OUT     (C),A			; A7..A0 = 0
+	CALL	DLY64			; DELAY
+	OR      $40
+	OUT     (C),A			; SET WR, A13..A8 = 0
+	CALL	DLY64			; DELAY
+	LD      A,$76
+	CALL	DLY64			; DELAY
+	LD	C, TMS_DATREG
+	OUT     (C),A			; SET VRAM $10000 = $76
+	CALL	DLY64			; DELAY
+	XOR     A
+	LD	C, TMS_CMDREG
+	OUT     (C),A			; A7..A0 = 0
+	CALL	DLY64			; DELAY
+
+	OUT     (C),A			; SET RD, A13..A8 = 0
+	CALL	DLY64			; DELAY
+	LD	C, TMS_DATREG
+	IN      A,(C)			; A = VRAM $10000
+	CALL	DLY64			; DELAY
+	CP      $76
+	JR      Z,VRAMSIZE_128K		; IF ITS $76, WE HAVE AT LEAST 128K
+
+	; OTHERWISE ITS ONLY 64K
+	JR      VRAMSIZE_DONE
+
+VRAMSIZE_128K:
+	; WE HAVE AT LEAST 128K
+	EX	AF, AF'
+	INC	A			; SET RETURN VALUE TO 1 FOR 128K
+	EX	AF, AF'
+
+	LD	A, $40			; CHECK TO SEE IF WE HAVE 192K (EXPANSION RAM INSTALLED)
+	LD	C, TMS_CMDREG
+	OUT	(C), A			; ENABLE EXANSION MEMORY ACCESS
+	CALL	DLY64			; DELAY
+	LD	A, $80 | 45
+	OUT	(C), A			; R#45 = $40 (MXC=1, MXD,MXS,DIY,DIX,EQ,MAJ=0)
+	CALL	DLY64			; DELAY
+
+	LD      A,1
+	OUT     (C),A
+	CALL	DLY64			; DELAY
+	LD      A,$8E
+	OUT     (C),A			; R#14 = 4 -> A16 = 0, A15..A14 = 1
+	CALL	DLY64			; DELAY
+	XOR     A
+	OUT     (C),A			; A7..A0 = 0
+	CALL	DLY64			; DELAY
+	OR      $40
+	OUT     (C),A			; SET WR, A13..A8 = 0
+	CALL	DLY64			; DELAY
+	LD      A,$5A
+	CALL	DLY64			; DELAY
+	LD	C, TMS_DATREG
+	OUT     (C),A			; SET VRAM $14000 = $76
+	CALL	DLY64			; DELAY
+	XOR     A
+	LD	C, TMS_CMDREG
+	OUT     (C),A			; A7..A0 = 0
+	CALL	DLY64			; DELAY
+	OUT     (C),A			; SET RD, A13..A8 = 0
+	CALL	DLY64			; DELAY
+	LD	C, TMS_DATREG
+	IN      A,(C)			; A = VRAM $14000
+	CALL	DLY64			; DELAY
+	CP      $5A
+	JR      NZ,VRAMSIZE_DONE	; IF ITS $5A, WE HAVE EXAPANSION VRAM
+
+	EX	AF, AF'
+	INC	A			; SET RETURN VALUE TO 2 FOR 192K
+	EX	AF, AF'
+
+VRAMSIZE_DONE:
+	XOR	A
+	LD	C, TMS_CMDREG
+	OUT	(C), A			; DISABLE EXANSION MEMORY ACCESS
+	CALL	DLY64			; DELAY
+	LD	A, $80 | 45
+	OUT	(C), A		;	 R#45 = $00 (MXC=0, MXD,MXS,DIY,DIX,EQ,MAJ=0)
+	CALL	DLY64			; DELAY
+
+	XOR     A
+	OUT     (C),A
+	CALL	DLY64			; DELAY
+	LD      A,$8E
+	OUT     (C),A			; R#14 = 0 -> A16..A14 = 0
+
+	EX	AF, AF'
+	RET
+
 ;
 ;----------------------------------------------------------------------
 ; TMS9918 DISPLAY CONTROLLER CHIP INITIALIZATION